Restarting Mac loses old Finder windows

Yeah, yeah, I sent feedback.

It's definitely losing any Finder windows open to external drives. I have 3 external drives attached and Finder lost all windows open to those drives.

Any suggested solutions other than to avoid restarting my computer unless absolutely essential and even then to write down a window list on a piece of paper? It isn't so bad when I only have a few windows open but on occasion I an be referring to a dozen or so.

neuroanatomist wrote:

When you restart the computer, external drives are unmounted and disconnected. They remount when the computer is finished booting up, but open windows will not be retained at least in my experience.

Yes, that is what I am finding. I transitioned from a 2012 iMac a month ago and this was not an issue on that computer with its High Sierra OS. In fact on that computer my boot drive was external so external drives had to be mounted before Finder could even start doing its thing. I suspect Sequoia is setting up Finder before it has finished mounting external drives and ignoring windows to folders that aren't "present" when Finder is doing its job.

Ironically, I wonder if an external boot would be the solution in this situation? I really would prefer not to have to go that route since the internal drive is so fast. Speed (especially a M4mini vs. 2012 iMac) was my real reason for getting a new computer in the first place. If I wanted to go that route and keep speed I'd probably have to fork out a lot more money for a thunderbolt drive.

Okay, an option. Here's an Applescript (courtesy of AI, but it works) that will create a folder on the desktop containing aliases to all open Finder windows when the script is run. Now I have to remember to run this to inventory the desktop before restarting the computer, but I don't have to make a written list. I simply have to open the folder, select all the aliases as a group and then right click to open them in new windows. I guess if I really wanted to, I could set up a launchd job to run this at intervals so I would likely almost always have an up to date folder.

I have to try it with a computer reboot but those aliases should still work since all my other aliases to external drive folders stay good after a reboot. This version will write over a folder with any previous set of aliases.

set folderName to "Finder Window Aliases"
set desktopPath to path to desktop folder as text
set targetFolderPath to desktopPath & folderName & ":"

tell application "Finder"
	-- Check if the target folder exists and delete it if it does
	if exists folder targetFolderPath then
		delete folder targetFolderPath
		delay 0.5 -- Give Finder a moment to process the deletion
	end if
	
	-- Create the new target folder on the desktop
	make new folder at desktopPath with properties {name:folderName}
	
	-- Get all open Finder windows
	set openWindows to every Finder window
	
	-- Iterate through each open window and create an alias
	repeat with aWindow in openWindows
		try
			set windowTarget to target of aWindow as alias
			set aliasName to name of (info for windowTarget) & " Alias"
			make new alias file at folder targetFolderPath to windowTarget with properties {name:aliasName}
		on error errMsg number errNum
			-- Handle cases where a window might not have a valid target (e.g., a search window)
			display dialog "Could not create alias for a window: " & errMsg buttons {"OK"} default button "OK"
		end try
	end repeat
end tell

Here's a companion script that will restore the Finder windows using the aliases made by the previous script.

You may encounter some typical Apple requests for permissions. Some don't occur again after the first granting. The scripts also use a folder called "Finder Windows Aliases" created on your desktop.

The location is hard-coded into the script. They could probably be modified to use the folder elsewhere. At first I wanted it on the desktop because of having to hand-rebuild the windows, but if you're using paired scripts (save as apps) then I guess the folder could be tucked away somewhere else, out of the way.

I use XMenu which puts an Applications folder disclosure list in my menu bar. I put a space in front of the two apps' names so they appear at the top of the Applications list.

tell application "Finder"
	-- Define the path to the folder containing the aliases
	set aliasFolderPath to (path to desktop folder as string) & "Finder Window Aliases:"
	
	-- Get a reference to the folder
	set aliasFolder to folder aliasFolderPath
	
	-- Get all files (which includes aliases) within the folder
	set aliasFiles to every file of aliasFolder
	
	-- Loop through each item in the folder
	repeat with anItem in aliasFiles
		-- Check if the item is an alias
		if kind of anItem is "alias" then
			-- Open the alias, which will open its original item
			open anItem
		end if
	end repeat
end tell